Arduino (23) 紅外線收發器+二輪智能車系統。

Arduino 玩到最後都要碰一下智能車才行。

兩輪智能車的結構大概就是兩顆減速直流馬達和一個L298N直流馬達驅動模組。

減速直流馬達是什麼??就是內建齒輪比讓輸出轉速降低，

就像是以前玩的軌道車，都會搭配1比3和1比4的齒輪比來降低輸出轉速。

而這台車送來發現兩顆輪子顏色不太一樣= =。


第一篇智能車專案就來搭配紅外線收發來控制前進、後退和方向。

程式如下 :

#include <IRremote.h>
#include <LedControl.h>
const int irReceiverPin = 2;
IRrecv irrecv(irReceiverPin);
decode_results results;

const byte IN1 = 3; 
const byte IN2 = 4;
const byte IN3 = 5;
const byte IN4 = 6;
//L298N的接腳宣告，控制兩顆馬達正反轉的輸出。 

void setup() {
  Serial.begin(115200);
  irrecv.enableIRIn();
  pinMode(IN1, OUTPUT);
  pinMode(IN2, OUTPUT);
  pinMode(IN3, OUTPUT);
  pinMode(IN4, OUTPUT);
}
void forward()
{
    digitalWrite(IN1, HIGH);
    digitalWrite(IN2, LOW);
    digitalWrite(IN3, HIGH);
    digitalWrite(IN4, LOW);
}
//前進的函式。

void backward()
{
    digitalWrite(IN1, LOW);
    digitalWrite(IN2, HIGH);
    digitalWrite(IN3, LOW);
    digitalWrite(IN4, HIGH);
}
//後退的函式。

void turnLeft()
{
    digitalWrite(IN1, HIGH);
    digitalWrite(IN2, LOW);
    digitalWrite(IN3, LOW);
    digitalWrite(IN4, LOW);
}
//左轉的函式。

void turnRight()
{
    digitalWrite(IN1, LOW);
    digitalWrite(IN2, LOW);
    digitalWrite(IN3, HIGH);
    digitalWrite(IN4, LOW);
}
//右轉的函式。

void stop()
{
    digitalWrite(IN1, LOW);
    digitalWrite(IN2, LOW);
    digitalWrite(IN3, LOW);
    digitalWrite(IN4, LOW);
}
//停止的函式。

void loop() {
  if (irrecv.decode(&results)){
            Serial.print("Protocol: "); 

            switch(results.decode_type) {
        case NEC:
          Serial.print("NEC");
          break;
        case SONY:
          Serial.print("SONY");
          break;
        case RC5:
          Serial.print("RC5");
          break;
        case RC6:
          Serial.print("RC6");
          break;
        default:
          Serial.print("Unknown encoding");
    }
  Serial.print("  irCode: ");         
  Serial.print(results.value);
//紅外線我直接沿用我前面之前寫的，我懶的在重新對編碼。

   if (results.value == 16753245) {
    forward();
    delay(100); }
   if (results.value == 16736925) {
    backward(); 
    delay(100); }
   if (results.value == 16738455) {
     turnLeft(); 
    delay(100); }
   if (results.value == 16724175) {
     turnRight(); 
    delay(100); }
   if (results.value == 16730805) {
      stop();
      }
    delay(1000);
    irrecv.resume();     
   }
}

遙控車不過就這樣而已嘛....

Arduino (22) 主、從端HC-05藍芽互相連通+PS類比搖桿+雙軸伺服馬達SG-90。

沒想到弄好一組對收藍芽後就可以變出很多種配置，

這次就來玩，主-PS搖桿，從-兩顆伺服馬達。

模組就之前介紹過了，這邊不多贅述。



至於跟(21)篇的主要差異在於這篇是傳遞類比訊號，而(21)篇是傳遞數位訊號。

上圖是Master配置。

上圖是Slave 配置。

成果感覺還行。

底座沒有固定，所以倒了，不管。


程式如下 :

Master--

#include <SoftwareSerial.h>
#include<Servo.h >　
SoftwareSerial BT(8, 9);
int valX, posX;
int valY, posY;
const byte pinX = A0;
const byte pinY = A1;

void setup() {
  Serial.begin(9600);
  Serial.println("BT is ready!");
  BT.begin(38400);
}

void loop() {
  valX = analogRead(pinX);
  valY = analogRead(pinY);
  posX = map(valX, 0, 1023, 0, 179);
  posY = map(valY, 0, 1023, 0, 179);

  BT.write(posX);
  BT.write(posY);
//從這裡將類比訊號傳到藍芽。

  delay(100);
}



Slave--
#include <SoftwareSerial.h>
#include<Servo.h >　
SoftwareSerial BT(8, 9);
Servo servo1;
Servo servo2;
int val1,val2;
void setup() {
  servo1.attach(3);
  servo2.attach(4);
  Serial.begin(9600);
  Serial.println("BT is ready!");
  BT.begin(38400);
}
void loop() {
  if (BT.available()>0) {
    val1 = BT.read(); 
    servo1.write(val1);
    delay(15);
  }
//接收類比訊號一，啟動一號馬達。

  if (BT.available()>0) {
    val2 = BT.read(); 
    servo2.write(val2);
    delay(15);
//接收類比訊號二，啟動二號馬達。
}
delay(15);
}


其實馬達還是有點抖動，delay這邊還可以再多試一下。

心得文 (2) 總算寫了21篇了。

花了一個多月的時間總算寫了21篇了，

其實這21篇就是大概把我買的所有模組都摸過一輪，

這些文章大部分都有兩個以上組合，

我不太喜歡只單一玩一種東西，太單調了。

程式架構方面大多是參考前輩文獻，而再用自己的想法做變化修改。


我預計慢慢增加到50篇，

過程大概就是模組的交叉組合、新購模組、新程式之類的，



最近寫文章的時間開始會拉長了，

因為要有新的IDEA，

還有本身的份內的工作也不少，

謝謝大家的指教與交流學習。

Arduino (21) 主、從端HC-05藍芽互相連通+紅外線觸發。

接下來這篇就不要用PC來控制藍芽風扇，

進階點來由紅外線避障模組來控制吧。


我本來想過完年去找我們公司的黃杯杯問一下Code，因為我自己寫風扇都不會動XD

結果剛剛被我寫成功了，整整寫了2天。



來看配置，下圖是Slave端。

一樣就是觸發繼電器給5V風扇。

再來是Master端，MCU用Nano，Trigger用一個紅外線避障模組。

結果就是這樣，程式寫了2天，總算成功了。

因為我C語言的能力不太好，畢竟是自學的，容易被卡小地方。


來看程式 :

Master端 :

#include <SoftwareSerial.h>
SoftwareSerial BT(8, 9);
int val;

void setup() {
  Serial.begin(9600);
  Serial.println("BT is ready!");
  pinMode(3,INPUT);
  BT.begin(38400);

}

void loop() {
  val=digitalRead(3);
  if(val!=HIGH)
//我也有卡這邊，我忘了紅外線避障是觸發低電位。
   {
     BT.write(100);
     delay(1000);
   }
delay(50);
}



Slave端 :

#include <SoftwareSerial.h>
SoftwareSerial BT(8, 9);
int val;
int pos=0;
void setup() {
  BT.begin(38400);
  Serial.begin(9600);
  pinMode(10, OUTPUT);

}

void loop() {
  if (BT.available()>0) {
    val = BT.read();
      if(val==100&&pos==0)
//這部分也可以用Boolean，切換開關模式，每次觸發改變HIGH、LOW與按下、未按下。

  {
   digitalWrite(10,HIGH);
   pos=1;
}
else if(val==100&&pos==1)
{
  digitalWrite(10,LOW);
   pos=0;
      }
   }
}


程式不長，但搞很久。

Arduino (20) 主、從端HC-05藍芽互相連通+序列阜輸入。

這東西是藍芽模組HC-05，而市面上有另一種叫HC-06的藍芽模組。

HC-05和HC-06不一樣的地方是HC-05多一個Enable-PIN，

可以進入AT模式設定Master或Slave，HC-06只能是Slave。

所以我直接用兩個HC-05比較方便。

首先先來進入AT模式，RX、TX、GND接好，Enable接3.3V，重要的是5VDC供電先不接，

還有要先灌"設定AT"的Code(如下)。

#include <SoftwareSerial.h> 

SoftwareSerial BT(8, 9);
// TX, RX (軟體RX要接硬體TX、硬體TX要接軟體RX)。

char val;

void setup() {
  Serial.begin(9600); 
  Serial.println("BT is ready!");
  BT.begin(38400);
}

void loop() {

  if (Serial.available()) {
    val = Serial.read();
    BT.print(val);
  }

  if (BT.available()) {
    val = BT.read();
    Serial.print(val);
  }
//程式LOOP主要功能就是收到什麼""指令""做什麼事。

}

按住板子上唯一的按鈕，然後插入DC5V供電，放掉按鈕，板子上的燈會呈現慢速閃動，

這樣就表示已進入AT，這時開啟序列阜就OK了。

後來有幾個程序要做，

1、輸入指令AT--確認AT連線。

2、輸入指令AT+ADDR?--回傳位置(Slave就好)。

3、輸入指令AT+ROLE=1 (Master)、輸入指令AT+ROLE=0 (Slave)。

4、輸入指令AT+BIND=儲存連線Slave藍芽位置。

Master端的Code如下:

#include <SoftwareSerial.h> 


SoftwareSerial BT(8, 9);

char val;

void setup() {
  Serial.begin(9600); 
  Serial.println("BT is ready!");

  BT.begin(38400);
//Baud Rate記得都要設38400。

}

void loop() {

  if (Serial.available()) {
    val = Serial.read();
    BT.print(val);
  }

  if (BT.available()) {
    val = BT.read();
    Serial.print(val);
  }
//這一樣是使用序列阜輸入訊息給Slave端。

}



接下來Slave端的Code如下:。

#include <SoftwareSerial.h>

SoftwareSerial BT(8, 9);

char val;

void setup() {
  BT.begin(38400);
  pinMode(10, OUTPUT);
//輸出定義在I/O 第10PIN。
}

void loop() {
  if (BT.available()) {
    val = BT.read();
    if (val == '1') {
      digitalWrite(10, 1);
      BT.println("ON");
       // Master端輸入字元"1"，10PIN輸出HIGH。

    } else if (val == '0') {
      digitalWrite(10, 0);
      BT.println("OFF");
      // Master端輸入字元"0"，10PIN輸出LOW。

    }
  }
}

成果像影片這樣，序列阜也會顯示開關。

這東西比較複雜點，細心點弄還是弄得出來的。

Arduino (19) WIFI MCU模組ESP8266 手機控制風扇開關。

這東西蠻厲害的，是一種物聯網的概念。

像是NANO板多了個WIFI功能，能用區域網路控制MCU的I/O輸出。

ESP8266 WiFi模塊 ESP-12E Lua 

配置就簡單的用繼電器去觸發電扇。

用IE或Chrome搜尋軟體輸入區域網路代碼就可以控制設備了。

程式如下 :

#include <ESP8266WiFi.h>

const char* ssid = "ACCOUNT"; 

//打上帳號。

const char* password = "PASSWORD";

//打上密碼。

WiFiServer server(80);

void setup() {

  Serial.begin(115200);

  delay(10);

  pinMode(2, OUTPUT);

  digitalWrite(2, 0);

//設定I/O輸出。

//這部分跟一般UNO不一樣，需要自己去插插看，

//13=D7、16=D0、上面的pinMode是2PIN，所以我們要插D4。

  

  Serial.println();

  Serial.println();

  Serial.print("Connecting to ");

  Serial.println(ssid);

  

  WiFi.mode(WIFI_STA);

  WiFi.begin(ssid, password);

  

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

    Serial.print(".");

  }

  Serial.println("");

  Serial.println("WiFi connected");

  

  server.begin();

  Serial.println("Server started");

  Serial.println(WiFi.localIP());

}

//因為我是抄範例的，所以上面一堆的序列阜監控和啟動WIFI程序就不多說，看得懂就好了。

void loop() {

  WiFiClient client = server.available();

  if (!client) {

    return;

  }

  Serial.println("new client");

  while(!client.available()){

    delay(1);

  }

  String req = client.readStringUntil('\r');

  Serial.println(req);

  client.flush();

  int val;

  if (req.indexOf("/gpio/0") != -1)

    val = 0;

  else if (req.indexOf("/gpio/1") != -1)

    val = 1;

  else {

    Serial.println("invalid request");

    client.stop();

    return;

  }

//這部分是最重要的，宣告一個變數(val)，區域網路就用這個變數去改變設備型態。

  digitalWrite(2, val);

  

  client.flush();

  String s = "HTTP/1.1 200 OK\r\nContent-Type: text/html\r\n\r\n<!DOCTYPE HTML>\r\n<html>\r\nGPIO is now ";

  s += (val)?"high":"low";

  s += "</html>\n";

  client.print(s);

  delay(1);

  Serial.println("Client disonnected");

}

用手機操控舵機也很簡單，就輸了一個角度變數，讓舵機執行你要轉的角度。

這地方就簡單做一個風扇控制就好了。

如果辛苦一點寫一個GUI上面做很多網址BUTTON就可以一鍵控制囉。

Arduino (18) 無線識別裝置RFID-RC522。

無線識別裝置RFID，採用TTL數位訊號傳遞資料，頻率大概在125K~13.56MHz。

上圖是RFID讀卡機，啟動後會不停的發送電磁波，當卡片接近時，卡片的線圈會和讀卡機的

電磁場產生共振，即可傳遞資料。

這東西就是所謂的卡片鎖，公司打卡(左)、電梯解鎖(右)都很普遍在運用。

配置先這樣，因為RFID程式本身很長，就簡單一上一顆LED燈就好了。

功能就是記憶兩組編碼(卡片式、鈕扣式)，接觸到讀卡機時，點亮LED燈，再接觸時關閉。

卡片式的和鈕扣式的都來玩一下。


程式如下 :

#include <MFRC522.h>   
#define RST_PIN      A0
#define SS_PIN       10 
#define LED 2

bool lockerSwitch = false;
//先預設關閉。

struct RFIDTag {
   byte uid[4];
   char *name;
};
//RFID編碼結構(4組十進位+名稱)。

struct RFIDTag tags[] = {
  {{64,97,93,89}, "Card_Type"},
  {{27,70,222,35}, "Button_Type"}
};
//卡片和鈕扣的編碼。

byte totalTags = sizeof(tags) / sizeof(RFIDTag);
MFRC522 mfrc522(SS_PIN, RST_PIN);

void locker(bool toggle) {
  if (toggle) {
      digitalWrite(LED,HIGH);
      delay(100);
  } else {
      digitalWrite(LED,LOW);
      delay(100);
  }
//開&關LED的函式。

}
void setup() {
  Serial.begin(9600);
  Serial.println();
  Serial.print("size of RFIDTag:");
  Serial.println(sizeof(RFIDTag));
  Serial.print("size of tag:");
  Serial.println(sizeof(tags));
  Serial.println("RFID reader is ready!");

  SPI.begin();
  mfrc522.PCD_Init();   
  pinMode(LED,OUTPUT);
  locker(lockerSwitch);
}
void loop() {

    if (mfrc522.PICC_IsNewCardPresent() && mfrc522.PICC_ReadCardSerial()) {
      byte *id = mfrc522.uid.uidByte;
      byte idSize = mfrc522.uid.size; 
      bool foundTag = false; 
   
      for (byte i=0; i<totalTags; i++) {
        if (memcmp(tags[i].uid, id, idSize) == 0) {
          Serial.println(tags[i].name);
          foundTag = true;
       
          lockerSwitch = !lockerSwitch;
          locker(lockerSwitch);       
          break;
          //讀到編碼資料且開、關鎖。

        }
      }
      if (!foundTag) {
        Serial.println("Wrong card!");
        //如果卡片編碼錯誤就顯示錯誤。

        if (lockerSwitch) {
          lockerSwitch = false;
          locker(lockerSwitch);
        }
      }
   
      mfrc522.PICC_HaltA();
    }
    //停止卡片狀態。

}

好用的東西，可以搭配任何開關模組，像是風扇和馬達等等...。

Arduino (17) LM35溫度感測器+1018 BJT開關電路。

本篇的主角，兩顆封裝長的一樣的電晶體，

左邊是LM35，右邊是1018 NPN BJT。

NPN電晶體開關就是基極收到HIGH，導通集極和射極(導通VCC+)使LED發光。

杜邦線的顏色我是隨邊挑的。

配置大概是這樣。

這篇我本來沒有要寫，只是套裝包裡有這個元件，買都買了就拿來用吧。

影片大概就是用手壓溫度會超過30度，給電晶體HIGH，導通LED正極電壓。

程式如下:

const int LM35=A1;

const int trigger=7;

int val =0; 

float temp = 0; 

void setup(){

pinMode(trigger,OUTPUT); 

Serial.begin(9600); 

}

void loop(){

val = analogRead(LM35); 

temp = (125*val)>>8; 

//算出溫度值，這我抄來的，我覺得沒很準。

Serial.print("Tep="); 

Serial.print(temp); 

Serial.println(" C"); 

delay(1000);

if (temp>=30) {

digitalWrite(trigger,HIGH); 

}

else if(temp<=30) {

  digitalWrite(trigger,LOW); 

  }

//大於30度給HIGH。

}

我的BJT 1018看DataSheet 射極和集極是顛倒的，我也不知道為什麼，

之前我在Layout微型中頻電路時也發現MMBT2222也有這種情形，

我在想是不是要接兩組1018，有空再試。

Arduino (16) B10K可變電阻類比控制排列LED燈與無源蜂鳴器。

B10K可變電阻，

左右PIN接5VDC+-，中間PIN判斷電阻值。

這種配置就是音響的音量調節旋鈕，旋鈕右轉，聲音愈大，LED燈也會亮愈多顆。

利用可變電阻的類比訊號去控制聲音和LED燈。

主要是處理類比資料的章節。



程式如下 :

const int LED1=2;
const int LED2=3;
const int LED3=4;
const int LED4=5;
const int LED5=6;
const int analogPin=A0;
const int buzzer=A1;
void setup(){
  for(int i=2;i<=6;i++){
 pinMode(i,OUTPUT);
 }
 pinMode(A0, INPUT);
 pinMode(buzzer, OUTPUT);
}
void loop(){
  int val = analogRead(analogPin);
//類比值宣告且定義。

  tone(buzzer,val*3,1);
//類比資料控制聲音，乘三是因為想讓聲音高一點。

  if(val<=50){
    digitalWrite(LED1,LOW);
    digitalWrite(LED2,LOW);
    digitalWrite(LED3,LOW);
    digitalWrite(LED4,LOW);
    digitalWrite(LED5,LOW);
  }
  else if(val<=100){
    digitalWrite(LED1,HIGH);
    digitalWrite(LED2,LOW);
    digitalWrite(LED3,LOW);
    digitalWrite(LED4,LOW);
    digitalWrite(LED5,LOW);
  }else if(val<=250){
    digitalWrite(LED1,HIGH);
    digitalWrite(LED2,HIGH);
    digitalWrite(LED3,LOW);
    digitalWrite(LED4,LOW);
    digitalWrite(LED5,LOW);
  }else if(val<=400){
    digitalWrite(LED1,HIGH);
    digitalWrite(LED2,HIGH);
    digitalWrite(LED3,HIGH);
    digitalWrite(LED4,LOW);
    digitalWrite(LED5,LOW);
   }else if(val<=650){
    digitalWrite(LED1,HIGH);
    digitalWrite(LED2,HIGH);
    digitalWrite(LED3,HIGH);
    digitalWrite(LED4,HIGH);
    digitalWrite(LED5,LOW);
   }else if(val<=800){
    digitalWrite(LED1,HIGH);
    digitalWrite(LED2,HIGH);
    digitalWrite(LED3,HIGH);
    digitalWrite(LED4,HIGH);
    digitalWrite(LED5,HIGH);
   }
//類比值愈大，燈亮的越多。

}


這是上班的時候想到的，就回來試一下。